Structural Liner in Jointed Tunnel

Problem Statement

Note

The project file for this example may be viewed/run in 3DEC.[1] The data files used are shown at the end of this example.

This is an example showing the application of a structural liner in the inside of a square tunnel. The geometry of the tunnel is shown in Figure 1. The block in the roof of the tunnel will fall if the tensile strength in the horizontal joint above it is not sufficient to support its weight. The model is used to simulate a 20 cm-thick concrete liner. The properties of the liner are

Table 1: Liner properties

Young’s modulus	15 GPa
Poisson’s ratio	0.15
thickness	0.2 m
friction between liner and rock	60^o
cohesion between liner and rock	0.5 MPa
tensile limit of contact between liner and rock	0.3 MPa
normal stiffness of contact	1 GN/m
shear stiffness of contact	1 GN/m

The input commands for this example are listed in liner.dat. Figure 2 shows the vertical displacement history of the roof block with no liner in place. The block is free to fall in this case.

The liner is installed using the structure liner create command as shown in the data file. Note the use of the tolerance keyword and the value of 1.0e-4. This is necessary because the blocks will have moved slightly during stress initialization. The tolerance value ensures that liner nodes will connect to each other if they are created within the specified distance.

Figure 3 shows the vertical displacement history of the unstable block with the concrete liner in place. It is clear that the liner is successful in preventing the rock fall. Moments that develop in the liner are shown in Figure 4.

Figure 1: Tunnel with unstable roof block

Figure 2: Vertical displacement history of unstable block without liner

Figure 3: Vertical displacement history of unstable block with liner

Figure 4: Moments in the liner

Data File

liner.dat

model new
model random 10000
model large-strain on
;
; Structural Liner Example Problem
;
block create brick -1 1 -1 1 -1 1

block cut joint-set dip-direction=180 dip=0  origin  0.0, 0.0, 0.5
block hide range plane dip 0 dip-direction 180  origin  0.0, 0.0, 0.5 above
block cut joint-set dip-direction=180 dip=0  origin  0.0, 0.0, 0.3
block hide range plane dip 0 dip-direction 180  origin  0.0, 0.0, 0.3 below
block cut joint-set dip=65 dip-direction=90  origin  .24, 0.0, 0.3
block cut joint-set dip=65 dip-direction=270 origin -.24, 0.0, 0.3
block hide off

block group 'rock'
block cut tunnel group 'exc' radial &
       face-1 -.3 -1.5 -.3  -.3 -1.5  .3  &
          .3 -1.5  .3   .3 -1.5 -.3  &
       face-2 -.3  1.5 -.3  -.3  1.5  .3  &
          .3  1.5  .3   .3  1.5 -.3
;
block zone generate edgelength .2

block face group 'surface' range group-intersection 'rock' 'exc'
block delete range group 'exc'

block zone cmodel assign elastic
block zone property density 2000 bulk = 1e9 shear = .7e9

block contact jmodel assign mohr
block contact property stiffness-shear 1e11 stiffness-normal 1e11
block contact property friction 100 cohesion 1e20 tension 1e20

block contact material-table default property stiffness-shear 1e11 ...
  stiffness-normal 1e11

; apply gravity load
model gravity 0 0 -10

block gridpoint apply velocity-x=0.0 range position-x -1.0
block gridpoint apply velocity-x=0.0 range position-x  1.0
block gridpoint apply velocity-y=0.0 range position-y -1.0
block gridpoint apply velocity-y=0.0 range position-y  1.0
block gridpoint apply velocity-z=0.0 range position-z -1.0
;
block history displacement-z position 0 0 0.3
;
model cycle 1200
model save 'liner1'

; reduce tensile strength of horizontal joint
block contact property tension = 0
block gridpoint initialize displacement 0 0 0
history delete

block history displacement-z position 0 0 0.3

model cycle 2000

model save 'liner1b'

===========================================

; now run with tunnel liner
model restore 'liner1'

; reduce tensile strength of horizontal joint
block contact property tension = 0
block gridpoint initialize displacement 0 0 0
history delete
block history displacement-z position 0 0 0.3

structure liner create by-block-face tolerance 1e-4 ...
  range group 'surface' position-z 0.295 0.305
structure liner property coupling-friction-shear 60 coupling-cohesion-shear .5e6 ...
  coupling-stiffness-normal 1e9 coupling-stiffness-shear 1e9
structure liner cmodel assign elastic
structure liner property young 15e9 poisson .15 thickness .20 ...
  coupling-yield-normal .3e6

model step 5000
model save 'liner2'

Endnote

[1]

This example is listed under the present document title in the i Examples dialog (use the menu command Help -> Examples… to access).