Spatial Variation in Damping
Note
To view this project in FLAC3D, use the menu command . The main data files is shown at the end of this example. The remaining data files can be found in the project.
This is an example of using a spatial variation in damping parameters, demonstrated by modifying the wave propagating in a column example. In the present example, two separate identical grids are constructed to enable a direct comparison. Both grids contain two layers: a stiff layer in the lower half, and a soft layer in the upper half. The left-hand grid has uniform Rayleigh stiffness damping, while the right-hand grid has two values for the damping coefficient, corresponding to the two materials, although the average damping coefficient is the same as that of the left-hand grid.
The velocity histories at the free surface are plotted in Figure 1 for both grids. Differences in response can be observed particularly in the second pulse (reflected from the material discontinuity).
![click to enlarge in a new window](../../../../../_images/dampingvariation-velocity.png)
Figure 1: Velocity histories at a free surface for spatial variation in damping.
Data File
Damping-SpatialVariation.dat
;---------------------------------------------------------------------
; Script file for dynamic problem Spatial variation in damping
;---------------------------------------------------------------------
model new
model large-strain off
fish automatic-create off
model title 'Spatial variation in damping'
model configure dynamic
; Create zones in two columns for comparison
zone create brick size 1,1,50 group 'Left'
zone create brick size 1,1,50 point 0 (2,0,0) group 'Right'
; Name the lower and upper section, and bottom faces
zone group 'Lower' slot 'Level'
zone group 'Upper' slot 'Level' range position-z 25,50
zone face group 'Bottom' range position-z 0.0
; Assign constitutive model and properties
zone cmodel assign elastic
zone property shear 1.00e7 bulk 2.0e7 density 2500 range group 'Lower'
zone property shear 0.25e7 bulk 0.5e7 density 2000 range group 'Upper'
; Assign damping
zone dynamic damping rayleigh 0.10 2.0 stiffness ...
range group 'Left'
zone dynamic damping rayleigh 0.02 2.0 stiffness ...
range group 'Right' and 'Lower' ; Non-uniform
zone dynamic damping rayleigh 0.18 2.0 stiffness ...
range group 'Right' and 'Upper' ; r.h. grid
; Assign boundary conditions
zone gridpoint fix velocity-z
zone face apply quiet-dip range group 'Bottom'
zone face apply quiet-strike range group 'Bottom'
fish define wave
if zone.dynamic.time.total > 0.5
wave = 0.0
else
wave = (1.0 - math.cos(4.0 * math.pi * zone.dynamic.time.total)) / 2.0
endif
end
zone face apply stress-xz -2e5 fish wave range group 'Bottom'
zone face apply velocity-normal 0 range group 'Bottom'
; Take some histories
zone history name='left' velocity-x position (0,0,50)
zone history name='right' velocity-x position (3,0,50)
model history name='time' dynamic time-total
model solve time-total 3.5
model save 'Damping-SpatialVariation'
Was this helpful? ... | Itasca Software © 2024, Itasca | Updated: Aug 13, 2024 |