Liner-Reinforced Beam

Problem Statement

Note

To view this project in FLAC2D, use the menu command Help ► Examples…. The main data files used are shown at the end of this example. The remaining data files can be found in the project.

A simply supported wooden beam (\(E\) = 8.6 GPa, \(\nu\) = 0, length of 2.5 m, height of 90 mm) has a concentrated load of 2000 N applied at its center. The beam is modeled with 40 FLAC2D zones. (Note that more zones are required to obtain the correct beam-theory solution. The system, as modeled, is too stiff; however, it is sufficient for the present example.) The FLAC2D model and the displacement field are shown in Figure 1.

The problem is rerun with a 10 mm thick steel liner (\(E\) = 200 GPa, \(\nu\) = 0.3) attached to the beam bottom. By setting the liner cohesive strength to a large value, no slip is allowed to occur at the liner-beam interface. (The liner stiffnesses are chosen using the liner-stiffness equation.) The displacement field of the liner-reinforced beam is shown in Figure 2. The presence of the liner has reduced the maximum mid-span deflection from 0.3 to 0.2 mm. Shear stresses have developed along the liner-beam interface (see Figure 3), and the maximum tensile \(xx\)-stress at the outer fiber of the liner is approximately 35 MPa (see Figure 4). The maximum tensile \(xx\)-stress at the liner mid-surface is 35 MPa. By setting the liner cohesive strength to zero, slip is allowed to occur along the liner-beam interface. The interface shear stresses go to zero, and the displacement field increases to almost match that of the unlined beam (see Figure 5). The liner continues to provide some stiffness to the composite system.

Figure 1: Displacement field of unlined wooden beam.

Figure 2: Displacement field of liner-reinforced wooden beam (no slip at liner-beam interface).

Figure 3: Shear stresses acting on the liner (no slip at liner-beam interface).

Figure 4: xx-stress carried in the outer fiber of the liner (no slip at liner-beam interface).

Figure 5: Displacement field of liner-reinforced wooden beam (full slip at liner-beam interface).

Data File

ReinforcedBeam.dat

; SEL Liner example application - Liner Reinforced Beam
model new
model large-strain off
model title 'Bending of a liner'
; Create zone geometry
zone create2d quadrilateral size (20,2) ...
                  point 0 (0,0)     point 1 (2.5,0) ...
                  point 2 (0,90e-3) point 3 (2.5,90e-3)
zone face skin
; Constitutive model and properties
zone cmodel assign elastic
zone property young 8.6e9 poisson 0
; Boundary Conditions
zone gridpoint fix velocity-x range position-x 0 position-y 0
zone gridpoint fix velocity-y range position-x 0 position-y 0
zone gridpoint fix velocity-y range position-x 2.5 position-y 0
zone gridpoint fix force-applied-y -2000 ...
               range position-x=1.25 position-y=90e-3
model save 'Start'

; --- Unlined case
model solve convergence 1.0
model save 'Unlined'
; Lined Case
model restore 'Start'
; Create liner and properties
structure liner create by-zone-face range group 'Bottom'
structure liner cmodel assign elastic
structure liner property young 200e9 poisson 0.3 ... ; steel
                      cross-sectional-area 10e-3 moi 8.33333333e-8
structure liner property coupling-stiffness-normal=1.9e12 ...
             coupling-stiffness-shear=1.9e12 coupling-cohesion-shear=1e20 ...
             coupling-yield-normal=1e20
structure mechanical damping combined-local
model solve convergence 1
model save 'Lined-NoSlip'
; Reduce liner shear strength
structure liner property coupling-cohesion-shear=0.0
model solve convergence 1
model save 'Lined-Slip'