Cantilever Beam with Applied Moment at Tip — Beam Elements

Problem Statement


To view this project in FLAC3D, use the menu command Help ► Examples…. Choose “Structure/Beam/Cantilever” and select “Cantilever.prj” to load. The main data files used are shown at the end of this example. The remaining data files can be found in the project.

A cantilever beam is subjected to an applied moment at its tip, as shown in Figure 1. This problem is an example of geometric nonlinearity, whereby deformations significantly alter the location of loads, so that equilibrium equations must be written with respect to the deformed geometry. Such problems can be solved by running FLAC3D in large-strain mode. The large-strain \(y\)-direction deflection at the beam tip (assuming that the material remains linearly elastic) is given by Cook et al. (1989, pp. 529-531) as

(1)\[{v_{\rm tip}\ =\ {E I \over {M}} \left(1 - \cos \biggl({M L \over E I}\biggr)\right)}\]
where: \(E\) = Young’s modulus; and
  \(I\) = second moment of inertia (\(I\) = \(I_y\) = \(I_z\)).

Figure 1: Cantilever beam with applied moment at tip.

Several properties and loading conditions are used in this example:

cross-sectional area (\(A\)) 0.006 m3
Young’s modulus (\(E\)) 200 GPa
Poisson’s ratio (\(\nu\)) 0.30
second moment with respect to local \(y\)-axis (I\(_y\)) 200 × 10-6 m4
second moment with respect to local \(z\)-axis (I\(_z\)) 200 × 10-6 m4
polar moment of inertia (\(J\)) 0.0
beam length (\(L\)) 10 m
applied moment at tip (\(M\)) 5 × 106 N-m

For these conditions, the theoretical tip deflection, \(v_{\rm tip}\), is given by equation (1) to be 5.477 m.

The FLAC3D model consists of 10 beam elements and 11 nodes. Boundary conditions corresponding to beam-theory behavior are imposed on all the nodes: namely, no translation in the \(z\)-direction, and no rotation about the \(x\)- and \(y\)-axes. The left end is fully fixed in all six degrees of freedom. And a moment vector aligned with the \(z\)-direction is applied to the node at the beam tip.

The final structural configuration is shown in Figure 2. The \(y\)-direction deflection at the beam tip equals 5.497 m, which is within 0.36% of the analytical solution.


Figure 2: Final structural configuration.


Cook, R. D., D. S. Malkus and M. E. Plesha. Concepts and Applications of Finite Element Analysis, Third Edition. New York: John Wiley & Sons Inc. (1989).

Data File


model new
model title ...
      'Cantilever beam, applied moment of 5e6 at tip (large-strain solution)'
; Create beam and assign properties
struct beam create by-line (0,0,0) (10,0,0) segments=10
struct beam property young=2e11 poisson=0.3
struct beam property cross-sectional-area=6e-3 moi-z=200e-6 ...
                     moi-y=200e-6 moi-polar=0
; Boundary conditions
struct node fix velocity-z rotation-x rotation-y ; restrict all non-beam modes
struct node fix velocity rotation range position-x 0     ;  fully fix left end
struct node apply moment=(0,0,5e6) range position-x 10   ; apply moment at tip
; Run the model
model large-strain on
model solve ratio-local=1e-7
model save 'Cantilever'