# Simple Beam — Two Equal Concentrated Loads — Beam Elements

Problem Statement

Note

To view this project in FLAC3D, use the menu command . Choose “Structure/Beam/ConcentratedLoads” and select “ConcentratedLoads.prj” to load. The main data files used are shown at the end of this example . The remaining data files can be found in the project.

A simply supported beam is loaded by two equal concentrated loads, symmetrically placed as shown in Figure 1. The shear and moment diagrams for this configuration are also shown in the figure. The shear force magnitude, \(V\), is equal to the applied concentrated load, \(P\). The maximum moment, \(M_{max}\), occurs between the two loads and is equal to \(P a\). The maximum deflection of the beam, \(\Delta_{\rm max}\), occurs at the center and is given by AISC (1980, p. 2-116) as

where: | \(E\) | = | Young’s modulus; and |

\(I\) | = | second moment of inertia (\(I\) = \(I_y\) = \(I_z\)). |

Several properties are used in this example:

Cross-sectional area (\(A\)) | 0.006 m^{3} |

Young’s modulus (\(E\)) | 200 GPa |

Poisson’s ratio (\(\nu\)) | 0.30 |

Second moment with respect to local \(y\)-axis (I\(_y\)) | 200 × 10^{-6} m^{4} |

Second moment with respect to local \(z\)-axis (I\(_z\)) | 200 × 10^{-6} m^{4} |

Polar moment of inertia (\(J\)) | 0.0 |

Point loads of \(P\) = 10,000 N are applied at the two locations shown in Figure 1.

The FLAC3D model consists of 10 beam elements and 11 nodes, as shown in Figure 2. The beam is created by issuing three separate `structure beam create by-line`

(all with an ID of 1) to ensure that nodes will lie exactly at the beam third points. Also, four
elements are created in the middle third to ensure that a node will lie at the exact beam center,
so that the displacement of this node can be compared with \(\Delta_{\rm max}\). Boundary
conditions corresponding to beam-theory behavior are imposed on all the nodes; namely, no
translation in the \(z\)-direction, and no rotation about the \(x\)- and \(y\)-axes.
Simple supports are specified at the beam ends by restricting translation in the
\(y\)-direction. Two point loads acting in the negative \(y\)-direction are applied at the
beam third points.

The displacement field is shown in Figure 3. The maximum displacement occurs at the beam center and equals 6.469×10^{-3} m, which corresponds exactly with the theoretical value of equation (1).

An alternative means of visualizing the displacement field for a small-strain simulation is to use the *Beam* plot item and specify a nonzero value for the deformation magnification factor. Figure 4 shows both the undeformed and deformed shapes.

Figure 5 and Figure 6 show the shear force and moment distributions, which correspond exactly with the theoretical solutions. These two plot items display these quantities in the element coordinate system using the Beam sign conventions. In this model, all element systems are aligned with the global system. Thus, the shear force and moment act in the element \(y\)- and \(z\)-directions, respectively.

The evolution of moment at \(x=1\) is shown in Figure 7 to reach a
steady-state value of 10,000 N-m. In this plot, we overlay two histories: one has sampled the
moment acting at the right end of element 1 and the other has sampled the moment acting at the left
end of element 2. If expressed in a consistent system, these two values should be identical, and
the plot demonstrates that they are. This is the case because the elements making up the beam have
a consistent orientation (having been created using the `structure beam create`

command). Note
that if we print the moment acting on each element in terms of the global system with the command

```
structure beam list force-node global range component-id 1 2
```

we find that the moment acting on the right end of element 1 is positive, while the moment acting on the left end of element 2 is negative. This is the correct behavior that satisfies equilibrium.

Reference

AISC. Manual of Steel Construction, Eighth Edition. Chicago: American Institute of Steel Construction Inc. (1980).

Data File

**ConcentratedLoads.dat**

```
model new
model large-strain off
model title ...
"Simple Beam --- Two Equal Concentrated Loads Symmetrically Placed"
; Create the beams; Ensure nodes will exist at the three points
struct beam create by-line ( 0, 0, 0) ( 3, 0, 0) id=1 segments=3
struct beam create by-line ( 3, 0, 0) ( 6, 0, 0) id=1 segments=4
struct beam create by-line ( 6, 0, 0) ( 9, 0, 0) id=1 segments=3
; Assign beam properties
struct beam property young=2e11 poisson=0.30 cross-sectional-area=6e-3 ...
moi-polar=0.0 moi-y=200e-6 moi-z=200e-6
; Specify model boundary conditions (including applied loads)
struct node fix velocity-z rotation-x rotation-y
; restrict all non-beam modes
struct node fix velocity-y range union position-x=0 position-x=9
; rollers at beam ends
struct node apply force=(0.0,-1e4,0.0) range union position-x=3 position-x=6
; apply point loads
; Setup histories for monitoring behavior.
struct beam history name='mom1' moment-z end 2 position (0.5,0,0)
; moment, right of element 1
struct beam history name='mom2' moment-z end 1 position (1.5,0,0)
; moment, left of element 2
; Bring the problem to equilibrium
model solve ratio-local=1e-7
model save 'ConcentratedLoads'
```

⇐ Tutorial: Braced Support of a Vertical Excavation | Cantilever Beam with Applied Moment at Tip — Beam Elements ⇒

Was this helpful? ... | 3DEC © 2019, Itasca | Updated: Feb 25, 2024 |