FLAC3D Theory and Background • Constitutive Models

Slope Stability with IMASS Model

Note

To view this project in FLAC3D, use the menu command Help ► Examples…. Choose “Imass/ Slope” and select “slope.prj” to load. The project’s main data file is shown at the end of this example.

The classical approach for assessing the stability of slopes using a Hoek-Brown constitutive model typically requires a pre-definition of damage to degrade the rock mass strength due to blasting very near the rock face and stress relaxation (which can extend up to 30% of the pit height behind the face). This is commonly done through applying a Disturbance Factor (D factor introduced by Hoek & Brown [2002] and assumption of elastic-perfectly plastic behavior for the rock mass. An example is shown Figure 1 for 500 m high, dry slope with an overall angle of 45° whereby a tri-angular D factor (Silva & Gomez, 2015) is pre-defined for the slope wall. Assuming a moderate rock mass quality (GSI 45, UCS 60 MPa, mi 15 and Ei 25 GPa), and 10° dilation angle, a factor of safety between 2.30 and 2.35 is calculated for the slope.

With IMASS the damage associated with stress relaxation is emergent as it considers the peak and post-peak strength envelopes for the rock mass and therefore can simulate the strain-softening between those envelopes as the rock mass undergoes plastic deformation. This eliminates the process of pre-defining damage (in terms of location and value) for the slope walls based on a subjective D Factor. In Figure 2 the slope in the moderate rock mass quality is re-analyzed using IMASS (in_weak_multecrit = 1.0). Note that in this model no damage is pre-defined.

Figure 1: Contour of instantaneous cohesion.

Figure 2: Contour of instantaneous friction.

Figure 3: Contour of FOS.

Data Files

slope.dat

model new
model large-strain off
model configure imass
model gravity 9.81
; Geometry an mesh
program call 'geometry.dat'
zone generate from-extruder
zone group 'Rock'
zone group 'Excavation' range group 'Block=Block 4'
zone face skin
; Boundary conditions
zone face apply velocity-y 0.0 range group 'North' or 'South'
zone face apply velocity-x 0.0 range group 'West' or 'East'
zone face apply velocity-z 0.0 range group 'Bottom'
; Model and properties
zone cmodel assign imass
zone initialize density 2500
zone property in_mod_youngintact 2.5e10
zone property in_stren_gsi 45
zone property in_stren_mi 15
zone property in_stren_ucsi 60e6
zone property in_bulking_dil 10
zone property in_weak_multecrit 1.0 
; Initilaize stresses
zone initialize-stresses
model solve elastic only
; Reset disp, vel and state
zone gridpoint initialize displacement (0,0,0)
zone gridpoint initialize velocity (0,0,0)
zone initialize state 0
;
zone relax excavate name 'Excavation' step 10000 range group 'Excavation'
model solve cycles 10001
zone delete range group 'Excavation'
model solve convergence 1 ;cycle 50000
model save 'slope-ini'
; IMASS to MC
program call 'fish.fis'
[IMASS_to_MC]
model solve convergence 1 cycle 15000
model save 'slope-temp.sav'
; 
[get_fs]
[FoS_to_group]
model save 'slope-fos'