Examples • Example Applications

Cemented Backfill Pillar Performance (FLAC2D)

Problem Statement

Note

This project reproduces Example 3 from FLAC 8.1. The project file for this example is available to be viewed/run in FLAC2D. The project’s main data files are shown at the end of this example.

This example studies the failure mode of a cemented backfill pillar, which is represented as a Mohr-Coulomb material. The pillar is three-dimensional in geometry, measuring 75 m in height by 27 m in length and 15 m in width. The material properties of the fill are

 density, $$\rho$$ 2100 kg/m^3 bulk modulus, $$K$$ 110 MPa shear modulus, $$G$$ 37 MPa cohesion, $$c$$ 0.1 MPa friction angle, $$\phi$$ 35 degrees tensile strength, ($$c/tan \phi$$) 0.2

Modeling Procedure

The analysis is made along a two-dimensional longitudinal section through the pillar center. The problem geometry and analysis plane are illustrated in Figure 1. A sliding interface is used along one of the orebody-sandfill contacts to allow downward settling of the sand during collapse. The boundary at the fill-ore contact (which is to be excavated) is given a roller boundary, and the right-hand boundary is fixed in the $$x$$- and $$y$$-directions; the top is free.

The modeling sequence is as follows. First, the gravity stresses are allowed to develop in the sandfill, and forces equilibrate across the interface. This is done elastically so that the fill will not yield. At equilibrium, displacements are reset, cohesion is set to the proper value, and vertical retreat mining is simulated by removing the $$x$$-direction fix along the left-face boundary in small increments that simulate the blast height (6 m). The $$x$$-displacement history is used to evaluate whether the system is coming to equilibrium at each step. Excavation is continued until active collapse of the pillar occurs.

Results

Figures 2 through 6 show displacements in the model at different blast heights. The model comes to equilibrium for the first three blast heights (6 m, 12 m and 18 m), as indicated by Figures 2, 3, and 4. Only a small localized displacement is shown in each of these figures.

At the fourth blast height (24 m), collapse of the pillar begins to occur. The failure is shown by the large region of downward movement that is shown in Figure 5. The failure is even more evident at the 30 m blast height, as shown by Figure 6. The plasticity states at collapse of the pillar are shown in Figure 7. A history of $$x$$-displacement at the left-face boundary is shown in Figure 8. This gridpoint history is reset at the fourth blast height and indicates that the model reaches equilibrium at this stage and collapses in the next.

Data Files

Initial.dat

model new

model large-strain on

; Create zone geometry
zone create2d quadrilateral point 0 (0,0) point 1 (15,0) ...
point 2 (0,75) point 3 (15,75) ...
size 15 75 group 'sand'

zone create2d quadrilateral point 0 (15,0) point 1 (16,0) ...
point 2 (15,75) point 3 (16,75) ...
size 1 75 group 'rock'

; Mechanical model and properties
zone cmodel assign mohr-coulomb
zone property density 2100 bulk 1.1E8 shear 3.7E7 ...
cohesion 1E10 friction 35 dilation 0 tension 1E10 ...
range group 'sand'

zone property density 2700 bulk 3.056E10 shear 2.292E10 ...
cohesion 1E7 friction 35 dilation 0 tension 1E6 ...
range group 'rock'

; Interfaces
zone interface create by-face separate range group 'sand' group 'rock'
zone interface node property stiffness-normal 1E9 stiffness-shear 1E9

; Boundary conditions
zone gridpoint fix velocity-x 0 range position-x 16
zone gridpoint fix velocity-x 0 range position-x 0
zone gridpoint fix velocity-y 0 range position-y 0

model gravity 9.81

model history mechanical unbalanced-maximum

model solve

model save 'initial-state'

program return


Step1.dat

; 6 m blast height

; Restore the initial state, reset the displacements,
;   and set the proper cohesion value.
; Vertical retreat mining is simulated by removing the x-direction fix along
;    the left-face boundary in small increments that simulate the blast height.

; The x-displacement history is used to evaluate whether the system
;   is coming to equilibrium at each step.
; Excavation is continued until active collapse of the pillar occurs.

model restore 'initial-state'

; Update proper properties (cohesion and tension)
zone property cohesion 1E5 tension 1.4E5 range group 'sand'

; Set non-zero inteface friction
zone interface node property friction 35

; Fix vertical displacement on right side
zone gridpoint fix velocity-y 0 range position-x 16

; reset the displacements and velocities
zone gridpoint initialize displacement (0,0)
zone gridpoint initialize velocity (0,0)

; simulate mining
zone gridpoint free velocity-x range position-x 0 position-y 6.5 12.5

; Histories
;history interval 100
zone history name 'y6' displacement-x position (0,6)
zone history name 'y12' displacement-x position (0,12)
zone history name 'y18' displacement-x position (0,18)
zone history name 'y24' displacement-x position (0,24)
zone history name 'y30' displacement-x position (0,30)
zone history name 'y36' displacement-x position (0,36)
zone history name 'y42' displacement-x position (0,42)
zone history name 'y48' displacement-x position (0,48)
zone history name 'y54' displacement-x position (0,54)

model solve

model save 'state-1'

program return


Step2.dat

; 12 m blasting height

model restore 'state-1'

zone gridpoint initialize displacement (0,0)
zone gridpoint initialize velocity (0,0)
zone gridpoint free velocity-x range position-x 0 position-y 12.5 18.5

model solve

model save 'state-2'

program return


Step3.dat

; 18 m blasting height

model restore 'state-2'

zone gridpoint initialize displacement (0,0)
zone gridpoint initialize velocity (0,0)
zone gridpoint free velocity-x range position-x 0 position-y 18.5 24.5

model solve

model save 'state-3'

program return


Step4.dat

; 24 m blasting height

model restore 'state-3'

model large-strain on

zone gridpoint initialize displacement (0,0)
zone gridpoint initialize velocity (0,0)
zone gridpoint free velocity-x range position-x 0 position-y 24.5 30.5

model solve

model save 'state-4'

program return


Step5.dat

; 30 m blasting height

model restore 'state-4'

zone gridpoint initialize displacement (0,0)
zone gridpoint initialize velocity (0,0)
zone gridpoint free velocity-x range position-x 0 position-y 30 36.5

; don't use solve.  Doesn't reach equilibrium
model cycle 2000

model save 'state-5'

program return